Kitaev honeycomb model

Hamiltonian of Kitaev honeycomb model is given by:

julia> function H₀(k, p) # Kitaev
            k1, k2 = k
            K₁ = 1
            K₂ = p

            hx = -K₂ * (sin(k2) - sin(k1) + sin(k1 - k2))
            hy = -K₁ * (sin(k1) + sin(k2))
            hz = K₁ * (cos(k1) + cos(k2) + 1)

            sx = [0 1; 1 0]
            sy = [0 -im; im 0]
            sz = [1 0; 0 -1]

            hx .* sx .+ hy .* sy .+ hz .* sz
       end

You can also use our preset Hamiltonian function KitaevHoneycomb to define the same Hamiltonian matrix as follows:

julia> H₀(k, p) = KitaevHoneycomb(k, p)

The band structure is computed as follows:

julia> H(k) = H₀(k, 0.5)
julia> showBand(H; value=false, disp=true)

Then we can compute the Chern numbers using FCProblem:

julia> prob = FCProblem(H);
julia> sol = solve(prob)

The output is:

FCSolution{Vector{Int64}, Int64}([-1, 1], 0)

The first argument TopologicalNumber in the named tuple is a vector that stores the first Chern number for each band. The vector is arranged in order of bands, starting from the one with the lowest energy. The second argument Total stores the total of the first Chern numbers for each band. Total is a quantity that should always return zero.

You can access these values as follows:

julia> sol.TopologicalNumber
2-element Vector{Int64}:
 -1
  1

julia> sol.Total
0

One-dimensional phase diagram is given by:

julia> param = range(-1, 1, length=1000);
julia> calcPhaseDiagram(H₀, param, "Chern"; plot=true)
(param = -1.0:0.002002002002002002:1.0, nums = [1 -1; 1 -1; … ; -1 1; -1 1])